/*********************************************************************NVMH3****
File:  $Id: velvety_tex.fx,v 1.2 2004/04/25 22:16:34 holger Exp $

Copyright NVIDIA Corporation 2002
TO THE MAXIMUM EXTENT PERMITTED BY APPLICABLE LAW, THIS SOFTWARE IS PROVIDED
*AS IS* AND NVIDIA AND ITS SUPPLIERS DISCLAIM ALL WARRANTIES, EITHER EXPRESS
OR IMPLIED, INCLUDING, BUT NOT LIMITED TO, IMPLIED WARRANTIES OF MERCHANTABILITY
AND FITNESS FOR A PARTICULAR PURPOSE.  IN NO EVENT SHALL NVIDIA OR ITS SUPPLIERS
BE LIABLE FOR ANY SPECIAL, INCIDENTAL, INDIRECT, OR CONSEQUENTIAL DAMAGES
WHATSOEVER (INCLUDING, WITHOUT LIMITATION, DAMAGES FOR LOSS OF BUSINESS PROFITS,
BUSINESS INTERRUPTION, LOSS OF BUSINESS INFORMATION, OR ANY OTHER PECUNIARY LOSS)
ARISING OUT OF THE USE OF OR INABILITY TO USE THIS SOFTWARE, EVEN IF NVIDIA HAS
BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGES.


Comments:
    A dead-simple combination of vertex and pixel shaders for dx8-class shading.
    Simple one-pass lambertian shading of a textured surface is the name
	of the game.

******************************************************************************/

/************* UN-TWEAKABLES **************/

float4x4 WorldIT : WorldInverseTranspose < string UIWidget="None"; >;
float4x4 WorldViewProj : WorldViewProjection < string UIWidget="None"; >;
float4x4 World : World < string UIWidget="None"; >;
float4x4 ViewI : ViewInverse < string UIWidget="None"; >;

/************* TWEAKABLES **************/

float3 LightPos : Position <
	string Object = "PointLight";
	string Space = "World";
> = {100.0f, 100.0f, 100.0f};

float3 DiffColor : DIFFUSE <
	string UIWidget = "Primary Color";
> = {0.5f, 0.5f, 0.5f};

float3 SpecColor : Specular <
	string UIWidget = "Color";
	string UIName = "Fuzz Color";
> = {0.7f, 0.7f, 0.75f};

float3 SubColor <
	string UIWidget = "Color";
	string UIName = "Under-Color";
> = {0.2f, 0.2f, 1.0f};

float RollOff <
    string UIWidget = "slider";
    float UIMin = 0.0;
    float UIMax = 1.0;
    float UIStep = 0.05;
	string UIName = "Edge Rolloff";
> = 0.3;

/*
float NormalSign <
    string UIWidget = "slider";
    float UIMin = -1.0;
    float UIMax = 1.0;
    float UIStep = 2.0;
    string UIName = "Normals Direction";
> = 1.0;
*/

///

texture ColorTexture : DIFFUSE
<
    string ResourceName = "default_color.dds";
    string TextureType = "2D";
>;

sampler2D ColorSampler = sampler_state
{
    Texture = <ColorTexture>;
    MinFilter = Linear;
    MagFilter = Linear;
    MipFilter = None;
};

/************* DATA STRUCTS **************/

/* data from application vertex buffer */
struct appdata {
    float3 Position	: POSITION;
    float4 UV		: TEXCOORD0;
    float4 Normal	: NORMAL;
};

/* data passed from vertex shader to pixel shader */
struct vertexOutput {
    float4 HPosition	: POSITION;
    float4 TexCoord0	: TEXCOORD0;
    float4 diffCol	: COLOR0;
    float4 specCol	: COLOR1;
};

/*********** vertex shader ******/

vertexOutput velvetVS(appdata IN)
{
    vertexOutput OUT;
    float3 Nn = normalize(mul(IN.Normal, WorldIT).xyz);
    // Nn.x = normalSign * Nn.x;
    // Nn.y = normalSign * Nn.y;
    // Nn.z = normalSign * Nn.z;
    float4 Po = float4(IN.Position.xyz,1);
    OUT.HPosition = mul(Po, WorldViewProj);
    float3 Pw = mul(Po, World).xyz;
    float3 Ln = normalize(LightPos - Pw);
    float ldn = dot(Ln,Nn);
    float diffComp = max(0,ldn);
    float3 diffContrib = diffComp * DiffColor;
    float subLamb = smoothstep(-RollOff,1.0,ldn) - smoothstep(0.0,1.0,ldn);
    subLamb = max(0.0,subLamb);
    float3 subContrib = subLamb * SubColor;
    OUT.TexCoord0 = IN.UV;
    float3 Vn = normalize(ViewI[3].xyz - Pw);
    float vdn = 1.0-dot(Vn,Nn);
    float3 vecColor = float4(vdn.xxx,1.0);
    OUT.diffCol = float4((subContrib+diffContrib).xyz,1);
    OUT.specCol = float4((vecColor*SpecColor).xyz,1);
    return OUT;
}

/********* pixel shader ********/

float4 velvetPS_t(vertexOutput IN) : COLOR
{
	return (IN.diffCol*tex2D(ColorSampler,IN.TexCoord0) + IN.specCol);
}

/*************/

technique Velvet {
    pass p0 {		
		VertexShader = compile vs_1_1 velvetVS();
		//ZEnable = true;
		//ZWriteEnable = true;
		//CullMode = None;
		PixelShader = compile ps_1_1 velvetPS_t();
    }
}

/***************************** eof ***/